VBS是一个可以在WIN系统下，用记事本敲好代码保存后（注意保存格式为ANSI），更改文件扩展名".vbs"即可直接运行使用的动态脚本语言。想想能够用到帮助自己一些机械而重复的工作，从网上搜索下，搬个砖，简单记录一下用法吧..
Section01 “控制键盘”
相对比于控制鼠标，控制键盘可就简单多了，不需要调用API （其实VBS脚本就不支持控制鼠标）。
- 定义变量和对象
用Dim来定义一个变量（WshShell）：
Dim WshShell
创建COM对象，具体用法：
object.CreateObject(strProgID[,strPrefix])
object ：WScript 对象。
strProgID ：表示要创建的对象的编程标识符 (ProgID) 的字符串值。
strPrefix ：可选。表示函数前缀的字符串值。
Dim WshShell
Set WshShell=WScript.CreateObject("WScript.Shell")
- 输出操作
VBS脚本中的指令"SendKeys"就是控制键盘的，具体用法：
WshShell.Sendkeys ""
双引号中就是要键盘输出的东西（也可以是按键比如Ctrl），比如WshShell.Sendkeys "23333" 就是模拟键盘输出23333。
另外，SendKeys可以同时发送多个键击。为此，可将每个键击按顺序排列在一起，以此来创建表示一系列键击的复合字符串参数。例如，要发送键击 a、b 和 c，则需要发送字符串参数 "abc" 。
PS：SendKeys方法将某些字符用作字符的修饰符（而不使用其本身的含义）。这组特殊的字符可包括圆括号、中括号、大括号，以及加号 "+"、插入记号 "^"、百分号 "%"和“非”符号 "~"，用大括号 "{}" 括起这些字符可以发送它们。
某些键击不生成字符（如 ENTER 和 TAB）。某些键击表示操作（如 BACKSPACE 和 BREAK）。要发送这些类型的键击，请发送下表中列出的参数：
空格键 " "
退格键 {BACKSPACE} 或 {BS} 或 {BKSP}
BREAK {BREAK}
DELETE {DELETE} 或 {DEL}
向下键 {DOWN}
向上键 {UP}
向左键 {LEFT}
向右键 {RIGHT}
END {END}
ENTER {ENTER} 或 ~
ESC {ESC}
TAB {TAB}
CAPS LOCK {CAPSLOCK}
HELP {HELP}
HOME {HOME}
INSERT {INSERT} 或 {INS}
NUM LOCK {NUMLOCK}
PAGE DOWN {PGDN}
PAGE UP {PGUP}
PRINT SCREEN {PRTSC}
SCROLL LOCK {SCROLLLOCK}
F1 {F1}
F2 {F2}
F3 {F3}
F4 {F4}
F5 {F5}
F6 {F6}
F7 {F7}
F8 {F8}
F9 {F9}
F10 {F10}
F11 {F11}
F12 {F12}
要发送由常规键击和 SHIFT、CTRL 或 ALT 组合而成的键盘字符，请创建表示该键击组合的复合字符串参数。可通过在常规键击之前添加一个或多个以下特殊字符来完成上述操作："SHIFT +"、"CTRL ^"、"ALT %"。
Section02 “控制鼠标”
VBS本身不支持用控制键盘的方式来控制鼠标，要使用下面这段代码的前提是你的系统上安装了Excel，并且宏指令可以正常调用，因为要用到Excel.Application对象调用电脑的API进行操作。具体是怎样实现的我也看不懂，网上搬砖，自行研究测试。具体代码如下：
Option Explicit
Dim WshShell
Dim oExcel, oBook, oModule
Dim strRegKey, strCode, x, y
Set oExcel = CreateObject("Excel.Application") '创建 Excel 对象
set WshShell = CreateObject("wscript.Shell")
strRegKey = "HKEY_CURRENT_USER\Software\Microsoft\Office\$\Excel\Security\AccessVBOM"
strRegKey = Replace(strRegKey, "$", oExcel.Version)
WshShell.RegWrite strRegKey, 1, "REG_DWORD"
Set oBook = oExcel.Workbooks.Add '添加工作簿
Set oModule = obook.VBProject.VBComponents.Add(1) '添加模块
strCode = _
"'Author: Demon" & vbCrLf & _
"'Website: http://demon.tw" & vbCrLf & _
"'Date: 2011/5/10" & vbCrLf & _
"Private Type POINTAPI : X As Long : Y As Long : End Type" & vbCrLf & _
"Private Declare Function SetCursorPos Lib ""user32"" (ByVal x As Long, ByVal y As Long) As Long" & vbCrLf & _
"Private Declare Function GetCursorPos Lib ""user32"" (lpPoint As POINTAPI) As Long" & vbCrLf & _
"Private Declare Sub mouse_event Lib ""user32"" Alias ""mouse_event"" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)" & vbCrLf & _
"Public Function GetXCursorPos() As Long" & vbCrLf & _
"Dim pt As POINTAPI : GetCursorPos pt : GetXCursorPos = pt.X" & vbCrLf & _
"End Function" & vbCrLf & _
"Public Function GetYCursorPos() As Long" & vbCrLf & _
"Dim pt As POINTAPI: GetCursorPos pt : GetYCursorPos = pt.Y" & vbCrLf & _
"End Function"
oModule.CodeModule.AddFromString strCode '在模块中添加 VBA 代码
x = oExcel.Run("GetXCursorPos") '获取鼠标 X 坐标
y = oExcel.Run("GetYCursorPos") '获取鼠标 Y 坐标
WScript.Echo x, y
oExcel.Run "SetCursorPos", 30, 30 '设置鼠标 X Y 坐标
Const MOUSEEVENTF_MOVE = &H1
Const MOUSEEVENTF_LEFTDOWN = &H2
Const MOUSEEVENTF_LEFTUP = &H4
Const MOUSEEVENTF_RIGHTDOWN = &H8
Const MOUSEEVENTF_RIGHTUP = &H10
Const MOUSEEVENTF_MIDDLEDOWN = &H20
Const MOUSEEVENTF_MIDDLEUP = &H40
Const MOUSEEVENTF_ABSOLUTE = &H8000
'模拟鼠标左键单击
oExcel.Run "mouse_event", MOUSEEVENTF_LEFTDOWN + MOUSEEVENTF_LEFTUP, 0, 0, 0, 0
'模拟鼠标左键双击（即快速的两次单击）
oExcel.Run "mouse_event", MOUSEEVENTF_LEFTDOWN + MOUSEEVENTF_LEFTUP, 0, 0, 0, 0
oExcel.Run "mouse_event", MOUSEEVENTF_LEFTDOWN + MOUSEEVENTF_LEFTUP, 0, 0, 0, 0
'模拟鼠标右键单击
oExcel.Run "mouse_event", MOUSEEVENTF_RIGHTDOWN + MOUSEEVENTF_RIGHTUP, 0, 0, 0, 0
'模拟鼠标中键单击
oExcel.Run "mouse_event", MOUSEEVENTF_MIDDLEDOWN + MOUSEEVENTF_MIDDLEUP, 0, 0, 0, 0
'关闭 Excel
oExcel.DisplayAlerts = False
oBook.Close
oExcel.Quit
本文由 蒟蒻 创作，转载自jvruo.com。
